|
|
"Wanderer On The Road" <non### [at] fakeaddresscom> wrote in message
news:3c6df0a4@news.povray.org...
>
> "bob h" <omn### [at] charternet> wrote in message
> news:3c68d377$1@news.povray.org...
>
> > Yeah, the render within a render can be pretty neat, as many online
> > galleries can attest to.
>
> Yes, though is there anything I can do to the painting scene that will
make
> it look slightly unfinished with out resorting to post trace effects in
like
> the gimp?
Any number of things are possible I suppose. One thing that comes to mind
is material_map to take the rendered image and make incomplete parts to it,
hence unfinished. Likewise by using a patterned layered texture with
image_map(s) as the main pigment.
Getting a oil painting look to it wouldn't be difficult, making different
brush stroke effects for each color region. Kind of an in-POV Photoshop
filter effects just by applying various normals and finishes for those color
regions.
bob h
Take a look at this simplified form of that:
camera {
location -2*z
right x*image_width/image_height
look_at 0
}
light_source {
0,1
translate <-5, 5, -30>
}
// textures for material map
#declare T0=texture {pigment {rgb 0}}
#declare T1=texture {pigment {rgb <0,1,0>}
normal {wrinkles 0.25 scale 0.025}
finish {specular 0.4 roughness 0.01}}
#declare T2=texture {pigment {rgb <1,1,0>}
normal {granite 0.125 scale 0.125}
finish {specular 0.2 roughness 0.025}}
#declare T3=texture {pigment {rgb <1,1,1>}
normal {bumps 0.1 scale 0.1}
finish {specular 0.3 roughness 0.0125}}
#declare T4=texture {pigment {rgb <0,1,1>}
normal {marble 0.1 scale 0.1 turbulence 1}
finish {specular 0.5 roughness 0.005}}
#declare T5=texture {pigment {rgb 1}}
plane {
z, 0
texture {
material_map {
png "materialmap.png" // 256 color bitmap (of your rendering)
once
interpolate 2
texture {T0} // index 0
#declare Index=1;
#while (Index<25)
texture {T1}
#declare Index=Index+1;
#end
#while (Index<100)
texture {T2}
#declare Index=Index+1;
#end
#while (Index<150)
texture {T3}
#declare Index=Index+1;
#end
#while (Index<255)
texture {T4}
#declare Index=Index+1;
#end
texture {T5} // index 255
}
translate -0.5
scale <4/3,1,1>*2
}
}
To get better resolution of colors and textures into your image you'll need
to increase the number of entries.
Post a reply to this message
|
|